// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if (get_flag(100,1) == 0) {
		message_dialog("The demon looks stunned. You entered the room and dealt it a devastating blow before it even got the chance to act. Before you can strike the final blow, however; the creature mumbles something and vanishes.","");
		set_flag(100,1,2);
		erase_char(11);
		end();
}

	if (get_flag(100,1) == 1) {
		message_dialog("The creature falls back. It did not expect the fight to go this way. It mumbles something and vanishes.","");
	erase_char(11);
		inc_flag(100,1,1);
}
	if (get_flag(100,1) == 2) {
		message_dialog("Marnok falters back once again. He breaths furiously and raises his hand and starts to mumble. Before you can send him back to the infernal planes, he vanishes.","");
		erase_char(6);
}
	if (get_flag(100,1) == 4) {
		message_dialog("Marnok grasps his stomach. He breathes heavily and raises his enormous hand. This time you are faster. You strike the lethal blow. A horrified look sweeps over Marnok.","He screams in rage as he burns back to the abyssal planes.");
}
	inc_flag(100,1,1);

	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

	if ((get_flag(100,1) == 0) && (get_flag(17,5) == 0)) {
		message_dialog("You've interrupted a meeting. One of the parties is the slith chief and his advisor, the other is a ten foot demon staring disinterestedly at you. _It would appear that your warriors have failed you, Messothsss._","The slith chief quivers. _Forgive me masster! I will deal with them perssonally!_ _NO!_ The demon booms. _You will fail where your warriors failed. I will dispose of them myself._ The demon flexes its muscles and attacks.");
		set_flag(100,1,1);
}
	if (get_flag(100,1) == 3) {
		message_dialog("You encounter the demon Marnok again. This time he is vivid with anger. He snarls furiously at you._Twice! Twice you defeated me mortals! Not this time! NOT in my chambers!_","");
		set_flag(100,1,4);
}

	if ((get_flag(100,1) == 0) && (get_flag(17,5) == 1)) {
		message_dialog("This laboratory belongs to a powerful looking mung demon. He inspects you curiously. _Mortals? This far in master's stronghold? Curious._","The demon doesn't speak another word. He flexes his mighty muscles and attacks.");
		set_flag(100,1,8);
}
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3)); 
break;
